«Changes
	«4/20/03; 8:58:17 AM by DW
		«Created. List all pages on a basic Manila website. I want to have an easy way to see them all, in one place.
		«Don't include items whose names begin with #.
		«Don't include the calendar (it's long, and comes first, and isn't the reason I'm doing this page, I want to find the functionality of the site, pages that may need to be in the user interface in some way).
on allnumeric (s) {
	local (i);
	for i = 1 to sizeof (s) {
		if not string.isnumeric (s [i]) {
			return (false)}};
	return (true)};
local (pta = html.getpagetableaddress ());
local (adrroot = pta^.adrSiteRootTable);
pta^.title = "List of all pages on this site";

local (htmltext = "", indentlevel = 0);
on add (s) {
	htmltext = htmltext + string.filledstring ("\t", indentlevel) + s + "\r"};

local (depth = 0);
on addlevel (adrparent, urlparent) {
	local (adr);
	add ("<ul>"); indentlevel++;
	for adr in adrparent {
		name = nameof (adr^);
		if name beginswith "#" {
			continue};
		if (depth == 0) and allnumeric (name) {
			continue};
		if typeof (adr^) == tabletype {
			local (urltable = urlparent + name + "/");
			add ("<li><a href=\"" + urltable + "\">" + name + "</a></li>");
			depth++;
			addlevel (adr, urltable);
			depth--}
		else {
			if string.lower (name) != "default" {
				add ("<li><a href=\"" + urlparent + name + "\">" + name + "</a></li>")}}};
	add ("</ul>"); indentlevel--};
addlevel (adrroot, adrroot^.["#ftpsite"].url);
return (htmltext)